ExcelAutomation

UserPreferences

1. 개요
2. 목록
1. 모든 워크 시트 내의 특정 셀 출력하기
2. 특정 셀 데이터를 텍스트 파일에다 쓰기.
3. XLS 파일을 CSV 파일로 변환하기
4. 이미지 집어넣기
5. 행 높이, 열 폭 변경하기
3. 링크

1 개요

VB 및 VBA(Visual Basic Addin) 스크립트를 이용한 엑셀 문서 처리를 다룬다.

게임 개발시 기획 측에서 엑셀 문서를 이용해 데이터를 넘기는 경우가 있는데, 이런 데이터를 프로그래머가 일일이 재가공하는 것은 노가다가 아니라고 할 수 없다. 그렇다고 프로그래머 측 기호에 맞춰서 기획 측에서 CSV 같은 걸 쓰는 것도 별로라고 생각한다. 왜냐하면 엑셀 문서에다 이미지 등을 넣어둬야지 작업이 편한 경우도 있기 때문이다. (CSV에는 텍스트 밖에 넣을 수 없다.)

결국 기획 측에서는 엑셀 문서 그대로 작업하고, 그 엑셀 파일을 프로그래머가 쓰기 편하게 만들어주는 중간 매개체가 필요하다는 말이다. 그 매개체로 생각한 것이 VB 스크립트다. 어설픈 툴 짜봤자 엑셀보다 편할 리도 만무하고...

문제는 WSH 스크립트만으로는 엑셀 기능을 완벽하게(?) 활용하기가 힘들다는 점인데... 일단 스크립트로 적당히 짜다가 힘들어지면, VisualBasic 콘솔 애플리케이션으로 넘어가는 방향으로...

2 목록

2.1 모든 워크 시트 내의 특정 셀 출력하기

'On Error Resume Next

Dim xlApp
Dim xlBook
Dim xlSheet
Dim xlRange
Dim i

Set xlApp = CreateObject("Excel.Application")
Set xlBook = xlApp.WorkBooks.Open("test.xls")

For Each xlSheet In xlBook.Sheets 
    For row=1 To 2 'xlSheet.Rows.Count
        For col=1 To 2 'xlSheet.Columns.Count
            WScript.Echo "(" & xlSheet.Name & "," & row & "," & col & ")=" & xlSheet.Cells(row, col)
        Next
    Next

    i = i + 1 
Next 

xlBook.close False
xlApp.quit





2.2 특정 셀 데이터를 텍스트 파일에다 쓰기.

Dim xlApp 'Excel.Application
Dim xlBook 'Excel.Workbook
Dim xlSht 'Excel.Worksheet

Set xlApp = CreateObject("Excel.Application")
Set xlBook = xlApp.WorkBooks.Open("test.xls")
Set xlSht = xlApp.activesheet

iRet = WriteResultFile(xlSht.Cells(1, 1).Value)
xlBook.close False
xlApp.quit

function WriteResultFile(strResult)
    const ForReading=1, ForWriting=2, ForAppending=8
    Dim fso, ts

    set fso = CreateObject("Scripting.FileSystemObject")
    set ts = fso.OpenTextFile("test.txt", ForWriting, True)
    ts.WriteLine(strResult)
    ts.Close
    WriteResultFile = 0
end function





2.3 XLS 파일을 CSV 파일로 변환하기

CsvFileProcessing 페이지도 참고하기 바란다.


On Error Resume Next

Dim xlApp
Dim xlBook
Dim xlSheet
Dim xlRange
Dim fso, file
Dim line, total
Dim XLSName, CSVName

const ForReading=1, ForWriting=2, ForAppending=8 

If WScript.Arguments.Count <> 2 Then
    WScript.Echo "Usage : convert.vbs excel_filename csv_filename"
    WScript.Quit
End If

Set XLSName = WScript.Arguments.Item(0)
Set CSVName = WScript.Arguments.Item(1)

Set xlApp = CreateObject("Excel.Application")
xlApp.Visible = True

Set xlBook = xlApp.WorkBooks.Open(XLSName)

Set fso = CreateObject("Scripting.FileSystemObject") 
Set file = fso.OpenTextFile(CSVName, ForWriting, True) 

For Each xlSheet In xlBook.Sheets  
    For row=2 To 10 'xlSheet.Rows.Count

        total = 0
        For col=1 To 15
            total = total + Len(xlSheet.Cells(row, col))
        Next
        
        If total = 0 Then Exit For
        
        line =        CSV(xlSheet.Cells(row,  1)) & "," '클래스
        line = line & CSV(xlSheet.Cells(row,  2)) & "," '타입
        line = line & CSV(xlSheet.Cells(row,  3)) & "," '이름
        line = line & CSV(xlSheet.Cells(row,  4)) & "," '가격
        line = line & CSV(xlSheet.Cells(row,  5)) & "," '최소
        line = line & CSV(xlSheet.Cells(row,  6)) & "," '최대
        line = line & CSV(xlSheet.Cells(row,  7)) & "," '스타일
        line = line & CSV(xlSheet.Cells(row,  8)) & "," '계절
        line = line & CSV(xlSheet.Cells(row,  9)) & "," '배색
        line = line & CSV(xlSheet.Cells(row, 10)) & "," '노출
        line = line & CSV(xlSheet.Cells(row, 11)) & "," '레이어
        line = line & CSV(xlSheet.Cells(row, 12)) & "," '범프
        line = line & CSV(xlSheet.Cells(row, 13)) & "," '속성
        line = line & CSV(xlSheet.Cells(row, 14)) & "," '메시
        line = line & CSV(xlSheet.Cells(row, 15))       '텍스쳐
        
        file.WriteLine(line)
    Next
Next

file.Close 
xlBook.close False
xlApp.quit

WScript.Echo "변환 완료"


' 임의의 셀을 CSV 형식으로 변환하기 위한 함수 
Function CSV(text) 
    Dim QuoteIndex 
    Dim CommaIndex 
    Dim LineFeedIndex
    Dim Result 
     
    Result        = text 
    QuoteIndex    = InStr(1, Result, """") 
    CommaIndex    = InStr(1, Result, ",") 
    LineFeedIndex = InStr(1, Result, VBLF) 
 
    If QuoteIndex <> 0 OR CommaIndex <> 0 OR LineFeedIndex <> 0 Then 
        While QuoteIndex <> 0 
            Result = Mid(Result, 1, QuoteIndex) & """" & Mid(Result, QuoteIndex+1) 
            QuoteIndex = InStr(QuoteIndex+2, Result, """") 
        Wend 
        Result = """" & Result & """" 
    End If 
     
    CSV = Result 
End Function 





2.4 이미지 집어넣기

Dim xlApp
Dim xlBook
Dim xlRange

Set xlApp = CreateObject("Excel.Application")
xlApp.Visible = True

Set xlBook = xlApp.WorkBooks.Open("d:\iteminfo.xls")

Set xlRange = xlApp.Range("A1")
InsertPicture xlApp.ActiveSheet, "d:\BED.BMP", xlRange, True, True

xlBook.close True '변경된 사항을 저장하고, 닫는다.
xlApp.quit

' 대상이 되는 셀에다가 이미지를 집어넣는다.
Sub InsertPicture(sheet, filename, cell, centerH, centerV)
    Dim picture
    Dim top
    Dim left
    Dim width
    Dim height
    
    ' import picture
    Set picture = sheet.Pictures.Insert(filename)
    
    ' 이미지 크기를 변경할 수 있다.
    'picture.Width = 100
    'picture.Height = 100
    
    ' determine positions
    top = cell.Top
    left = cell.Left
    
    If centerH Then
        width = cell.Offset(0, 1).Left - cell.Left
        left = left + width / 2 - picture.Width / 2
        If l < 1 Then l = 1
    End If
    
    If centerV Then
        height = cell.Offset(1, 0).Top - cell.Top
        top = top + height / 2 - picture.Height / 2
        If top < 1 Then top = 1
    End If
    
    ' position picture
    picture.Top = top
    picture.Left = left
    
    Set picture = Nothing
End Sub





2.5 행 높이, 열 폭 변경하기

Sub SetColumnWidth(sheet, col, width)
    If col < 1 OR col > 256 Then Exit Sub
    sheet.Columns(col).ColumnWidth = width
End Sub

Sub SetRowHeight(sheet, row, height)
    If row < 1 OR row > 65536 Then Exit Sub
    sheet.Rows(row).RowHeight = height
End Sub

3 링크

• Office Solutions Development > Excel
  
엑셀 관련 프로그램 개발 리소스 모음

• Excel Object
  
Excel Object 레퍼런스

• Microsoft Excel Objects
  
Microsoft Office Developer Forum > Office 97 Programmer's Guide > Microsoft Excel Objects


• Automating Excel Using the Excel Object Model
  
C#과 VisualBasic을 이용한 각종 자동화 예제

• Create User Accounts from Information in an Excel Spreadsheet
  
엑셀 파일 내부에 있는 데이터를 이용해 자동으로 계정 생성하기. 엑셀 자동화 예제라고 할 수 있다.


• VBA Samples for Working with Excel 2003 Worksheets
  
Excel 2003 VBA 스크립트 예제

• Import Web Content into Your Excel Workbook
  
VBA 스크립트로, IE 내부에 있는 HTTP 기능을 이용하여, 파일을 다운로드받아 셀에다 집어넣기. 어디다 쓰는가는 미지수다.


• Placing images in Excel using automation
  
MFC 환경에서 엑셀 문서에다 이미지 집어넣기

• C++ Builder working with MS Excel
  
CppBuilder로 엑셀을 다루는 방법에 관한 위키다. 별 내용 없다. 하지만 CppBuilder는 항상 예제에 굶주려 있기 때문에...

• BasicExcel - A Class to Read and Write to Microsoft Excel
  
  
• http://www.iexceller.com/
  
엑셀러(-_-) 권현욱 씨의 홈페이지. 엑셀 및 엑셀 VBA 관련 강좌가 있는 사이트이다.

• http://www.exceltip.com/
  
사이트 이름에서 알 수 있듯이 엑셀과 관련된 각종 팁들이 올라와 있는 사이트이다.

• see also COM, VisualBasic
  

• CategoryAutomation, CategoryTools